Add installer

Installer/scripts/code.pas

@@ -0,0 +1,313 @@
+{
+    --- TYPES AND VARIABLES ---
+}
+type
+	TProduct = record
+		File: String;
+		Title: String;
+		Parameters: String;
+		ForceSuccess : boolean;
+		InstallClean : boolean;
+		MustRebootAfter : boolean;
+	end;
+
+	InstallResult = (InstallSuccessful, InstallRebootRequired, InstallError);
+
+var
+	installMemo, downloadMemo, downloadMessage: string;
+	products: array of TProduct;
+	delayedReboot, isForcedX86: boolean;
+	DependencyPage: TOutputProgressWizardPage;
+
+procedure AddProduct(filename, parameters, title, size, url: string; forceSuccess, installClean, mustRebootAfter : boolean);
+{
+    Adds a product to the list of products to download.
+    Parameters:
+        filename: the file name under which to save the file
+        parameters: the parameters with which to run the file
+        title: the product title
+        size: the file size
+        url: the URL to download from
+        forceSuccess: whether to continue in case of setup failure
+        installClean: whether the product needs a reboot before installing
+        mustRebootAfter: whether the product needs a reboot after installing
+}
+var
+	path: string;
+	i: Integer;
+begin
+	installMemo := installMemo + '%1' + title + #13;
+
+	path := ExpandConstant('{src}{\}') + CustomMessage('DependenciesDir') + '\' + filename;
+	if not FileExists(path) then begin
+		path := ExpandConstant('{tmp}{\}') + filename;
+
+		if not FileExists(path) then begin
+			isxdl_AddFile(url, path);
+
+			downloadMemo := downloadMemo + '%1' + title + #13;
+			downloadMessage := downloadMessage + '	' + title + ' (' + size + ')' + #13;
+		end;
+	end;
+
+	i := GetArrayLength(products);
+	SetArrayLength(products, i + 1);
+	products[i].File := path;
+	products[i].Title := title;
+	products[i].Parameters := parameters;
+	products[i].ForceSuccess := forceSuccess;
+	products[i].InstallClean := installClean;
+	products[i].MustRebootAfter := mustRebootAfter;
+end;
+
+function SmartExec(product : TProduct; var resultcode : Integer): boolean;
+{
+    Executes a product and returns the exit code.
+    Parameters:
+        product: the product to install
+        resultcode: the exit code
+}
+begin
+	if (LowerCase(Copy(product.File, Length(product.File) - 2, 3)) = 'exe') then begin
+		Result := Exec(product.File, product.Parameters, '', SW_SHOWNORMAL, ewWaitUntilTerminated, resultcode);
+	end else begin
+		Result := ShellExec('', product.File, product.Parameters, '', SW_SHOWNORMAL, ewWaitUntilTerminated, resultcode);
+	end;
+end;
+
+function PendingReboot: boolean;
+{
+    Checks whether the machine has a pending reboot.
+}
+var	names: String;
+begin
+	if (RegQueryMultiStringValue(HKEY_LOCAL_MACHINE, 'SYSTEM\CurrentControlSet\Control\Session Manager', 'PendingFileRenameOperations', names)) then begin
+		Result := true;
+	end else if ((RegQueryMultiStringValue(HKEY_LOCAL_MACHINE, 'SYSTEM\CurrentControlSet\Control\Session Manager', 'SetupExecute', names)) and (names <> ''))  then begin
+		Result := true;
+	end else begin
+		Result := false;
+	end;
+end;
+
+function InstallProducts: InstallResult;
+{
+    Installs the downloaded products
+}
+var
+	resultCode, i, productCount, finishCount: Integer;
+begin
+	Result := InstallSuccessful;
+	productCount := GetArrayLength(products);
+
+	if productCount > 0 then begin
+		DependencyPage := CreateOutputProgressPage(CustomMessage('depinstall_title'), CustomMessage('depinstall_description'));
+		DependencyPage.Show;
+
+		for i := 0 to productCount - 1 do begin
+			if (products[i].InstallClean and (delayedReboot or PendingReboot())) then begin
+				Result := InstallRebootRequired;
+				break;
+			end;
+
+			DependencyPage.SetText(FmtMessage(CustomMessage('depinstall_status'), [products[i].Title]), '');
+			DependencyPage.SetProgress(i, productCount);
+
+			if SmartExec(products[i], resultCode) then begin
+				//setup executed; resultCode contains the exit code
+				if (products[i].MustRebootAfter) then begin
+					//delay reboot after install if we installed the last dependency anyways
+					if (i = productCount - 1) then begin
+						delayedReboot := true;
+					end else begin
+						Result := InstallRebootRequired;
+					end;
+					break;
+				end else if (resultCode = 0) or (products[i].ForceSuccess) then begin
+					finishCount := finishCount + 1;
+				end else if (resultCode = 3010) then begin
+					//Windows Installer resultCode 3010: ERROR_SUCCESS_REBOOT_REQUIRED
+					delayedReboot := true;
+					finishCount := finishCount + 1;
+				end else begin
+					Result := InstallError;
+					break;
+				end;
+			end else begin
+				Result := InstallError;
+				break;
+			end;
+		end;
+
+		//only leave not installed products for error message
+		for i := 0 to productCount - finishCount - 1 do begin
+			products[i] := products[i+finishCount];
+		end;
+		SetArrayLength(products, productCount - finishCount);
+
+		DependencyPage.Hide;
+	end;
+end;
+
+{
+    --------------------
+    INNO EVENT FUNCTIONS
+    --------------------
+}
+
+function PrepareToInstall(var NeedsRestart: boolean): String;
+{
+    Before the "preparing to install" page.
+    See: http://www.jrsoftware.org/ishelp/index.php?topic=scriptevents
+}
+var
+	i: Integer;
+	s: string;
+begin
+	delayedReboot := false;
+
+	case InstallProducts() of
+		InstallError: begin
+			s := CustomMessage('depinstall_error');
+
+			for i := 0 to GetArrayLength(products) - 1 do begin
+				s := s + #13 + '	' + products[i].Title;
+			end;
+
+			Result := s;
+			end;
+		InstallRebootRequired: begin
+			Result := products[0].Title;
+			NeedsRestart := true;
+
+			//write into the registry that the installer needs to be executed again after restart
+			RegWriteStringValue(HKEY_CURRENT_USER, 'SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnce', 'InstallBootstrap', ExpandConstant('{srcexe}'));
+			end;
+	end;
+end;
+
+function NeedRestart : boolean;
+{
+    Checks whether a restart is needed at the end of install
+    See: http://www.jrsoftware.org/ishelp/index.php?topic=scriptevents
+}
+begin
+	Result := delayedReboot;
+end;
+
+function UpdateReadyMemo(Space, NewLine, MemoUserInfoInfo, MemoDirInfo, MemoTypeInfo, MemoComponentsInfo, MemoGroupInfo, MemoTasksInfo: String): String;
+{
+    Just before the "ready" page.
+    See: http://www.jrsoftware.org/ishelp/index.php?topic=scriptevents
+}
+var
+	s: string;
+begin
+	if downloadMemo <> '' then
+		s := s + CustomMessage('depdownload_memo_title') + ':' + NewLine + FmtMessage(downloadMemo, [Space]) + NewLine;
+	if installMemo <> '' then
+		s := s + CustomMessage('depinstall_memo_title') + ':' + NewLine + FmtMessage(installMemo, [Space]) + NewLine;
+
+	s := s + MemoDirInfo + NewLine + NewLine + MemoGroupInfo
+
+	if MemoTasksInfo <> '' then
+		s := s + NewLine + NewLine + MemoTasksInfo;
+
+	Result := s
+end;
+
+function NextButtonClick(CurPageID: Integer): boolean;
+{
+    At each "next" button click
+    See: http://www.jrsoftware.org/ishelp/index.php?topic=scriptevents
+}
+begin
+	Result := true;
+
+	if CurPageID = wpReady then begin
+		if downloadMemo <> '' then begin
+			//change isxdl language only if it is not english because isxdl default language is already english
+			if (ActiveLanguage() <> 'en') then begin
+				ExtractTemporaryFile(CustomMessage('isxdl_langfile'));
+				isxdl_SetOption('language', ExpandConstant('{tmp}{\}') + CustomMessage('isxdl_langfile'));
+			end;
+			//isxdl_SetOption('title', FmtMessage(SetupMessage(msgSetupWindowTitle), [CustomMessage('appname')]));
+
+			if SuppressibleMsgBox(FmtMessage(CustomMessage('depdownload_msg'), [downloadMessage]), mbConfirmation, MB_YESNO, IDYES) = IDNO then
+				Result := false
+			else if isxdl_DownloadFiles(StrToInt(ExpandConstant('{wizardhwnd}'))) = 0 then
+				Result := false;
+		end;
+	end;
+end;
+
+{
+    -----------------------------
+    ARCHITECTURE HELPER FUNCTIONS
+    -----------------------------
+}
+
+function IsX86: boolean;
+{
+    Gets whether the computer is x86 (32 bits).
+}
+begin
+	Result := isForcedX86 or (ProcessorArchitecture = paX86) or (ProcessorArchitecture = paUnknown);
+end;
+
+function IsX64: boolean;
+{
+    Gets whether the computer is x64 (64 bits).
+}
+begin
+	Result := (not isForcedX86) and Is64BitInstallMode and (ProcessorArchitecture = paX64);
+end;
+
+function IsIA64: boolean;
+{
+    Gets whether the computer is IA64 (Itanium 64 bits).
+}
+begin
+	Result := (not isForcedX86) and Is64BitInstallMode and (ProcessorArchitecture = paIA64);
+end;
+
+function GetString(x86, x64, ia64: String): String;
+{
+    Gets a string depending on the computer architecture.
+    Parameters:
+        x86: the string if the computer is x86
+        x64: the string if the computer is x64
+        ia64: the string if the computer is IA64
+}
+begin
+	if IsX64() and (x64 <> '') then begin
+		Result := x64;
+	end else if IsIA64() and (ia64 <> '') then begin
+		Result := ia64;
+	end else begin
+		Result := x86;
+	end;
+end;
+
+function GetArchitectureString(): String;
+{
+    Gets the "standard" architecture suffix string.
+    Returns either _x64, _ia64 or nothing.
+}
+begin
+	if IsX64() then begin
+		Result := '_x64';
+	end else if IsIA64() then begin
+		Result := '_ia64';
+	end else begin
+		Result := '';
+	end;
+end;
+
+procedure SetForceX86(value: boolean);
+{
+    Forces the setup to use X86 products
+}
+begin
+	isForcedX86 := value;
+end;

Installer/scripts/isxdl/english.ini

@@ -0,0 +1,49 @@
+[strings]
+; General
+100=File download
+101=Do you want to cancel the download?
+102=%1 (%2 of %3)
+103=%1 KB
+104=%1 KB of %2 KB (%3%)
+
+; Status information
+110=Getting file information...
+111=Redirecting to %1
+112=Sending request...
+113=Resolving %1
+114=Connected to %1
+115=Receiving...
+116=Connecting to %1
+
+; Error messages
+120=Error connecting to the internet.\n\n%1
+121=Error opening %1.\n\nThe server returned status code %2.
+122=Error reading URL.\n\n%1
+123=Error writing file %1.\n\n%2
+124=Error opening file %1.\n\n%2
+125='%1' is an invalid URL.
+126=Error opening %1.\n\n%2
+127=Error sending request.\n\n%1
+128=Unsupported protocol. Only HTTP and FTP protocols are supported.
+129=Failed to connect to %1.\n\n%2
+130=Failed to query status code.\n\n%1
+131=Error requesting file.\n\n%1
+
+; Other
+144=About...
+146=Download
+147=Setup is now downloading additional files to your computer.
+
+; labels
+160=File:
+161=Speed:
+162=Status:
+163=Elapsed Time:
+164=Remaining Time:
+165=Current File:
+166=Overall Progress:
+167=Cancel
+168=OK
+169=User Name and Password
+170=User Name:
+171=Password:

Installer/scripts/isxdl/isxdl.iss

@@ -0,0 +1,14 @@
+[Files]
+Source: "scripts\isxdl\isxdl.dll"; Flags: dontcopy
+
+[Code]
+procedure isxdl_AddFile(URL, Filename: PAnsiChar);
+external 'isxdl_AddFile@files:isxdl.dll stdcall';
+
+function isxdl_DownloadFiles(hWnd: Integer): Integer;
+external 'isxdl_DownloadFiles@files:isxdl.dll stdcall';
+
+function isxdl_SetOption(Option, Value: PAnsiChar): Integer;
+external 'isxdl_SetOption@files:isxdl.dll stdcall';
+
+[Setup]

Installer/scripts/products.iss

@@ -0,0 +1,27 @@
+#include "isxdl\isxdl.iss"
+
+[CustomMessages]
+DependenciesDir=MyProgramDependencies
+
+en.depdownload_msg=The following applications are required before setup can continue:%n%n%1%nDownload and install now?
+
+en.depdownload_memo_title=Download dependencies
+
+en.depinstall_memo_title=Install dependencies
+
+en.depinstall_title=Installing dependencies
+
+en.depinstall_description=Please wait while Setup installs dependencies on your computer.
+
+en.depinstall_status=Installing %1...
+
+en.depinstall_missing=%1 must be installed before setup can continue. Please install %1 and run Setup again.
+
+en.depinstall_error=An error occured while installing the dependencies. Please restart the computer and run the setup again or install the following dependencies manually:%n
+
+en.isxdl_langfile=
+
+[Code]
+#include "code.pas"
+
+[Setup]

Installer/scripts/products/dotnetfx46.iss

@@ -0,0 +1,28 @@
+; requires Windows 10, Windows 7 Service Pack 1, Windows 8, Windows 8.1, Windows Server 2008 R2 SP1, Windows Server 2008 Service Pack 2, Windows Server 2012, Windows Server 2012 R2, Windows Vista Service Pack 2
+; WARNING: express setup (downloads and installs the components depending on your OS) if you want to deploy it on cd or network download the full bootsrapper on website below
+; https://www.microsoft.com/en-US/download/details.aspx?id=49982
+
+[CustomMessages]
+dotnetfx46_title=.NET Framework 4.6.1
+
+dotnetfx46_size=1 MB - 65 MB
+
+;http://www.microsoft.com/globaldev/reference/lcid-all.mspx
+en.dotnetfx46_lcid=
+
+[Code]
+const
+	dotnetfx461_url = 'http://download.microsoft.com/download/3/5/9/35980F81-60F4-4DE3-88FC-8F962B97253B/NDP461-KB3102438-Web.exe';
+
+procedure dotnetfx46(minVersion: integer);
+begin
+	if (not netfxinstalled(NetFx4x, '') or (netfxspversion(NetFx4x, '') < minVersion)) then
+		AddProduct('dotnetfx46.exe',
+			CustomMessage('dotnetfx46_lcid') + ' /passive /norestart',
+			CustomMessage('dotnetfx46_title'),
+			CustomMessage('dotnetfx46_size'),
+			dotnetfx461_url,
+			false, false, false);
+end;
+
+[Setup]

Installer/scripts/products/dotnetfxversion.iss

@@ -0,0 +1,94 @@
+[Code]
+type
+	NetFXType = (NetFx10, NetFx11, NetFx20, NetFx30, NetFx35, NetFx40Client, NetFx40Full, NetFx4x);
+
+const
+	netfx11plus_reg = 'Software\Microsoft\NET Framework Setup\NDP\';
+
+function netfxinstalled(version: NetFXType; lcid: string): boolean;
+var
+	regVersion: cardinal;
+	regVersionString: string;
+begin
+	if (lcid <> '') then
+		lcid := '\' + lcid;
+
+	if (version = NetFx10) then begin
+		RegQueryStringValue(HKLM, 'Software\Microsoft\.NETFramework\Policy\v1.0\3705', 'Install', regVersionString);
+		Result := regVersionString <> '';
+	end else begin
+		case version of
+			NetFx11:
+				RegQueryDWordValue(HKLM, netfx11plus_reg + 'v1.1.4322' + lcid, 'Install', regVersion);
+			NetFx20:
+				RegQueryDWordValue(HKLM, netfx11plus_reg + 'v2.0.50727' + lcid, 'Install', regVersion);
+			NetFx30:
+				RegQueryDWordValue(HKLM, netfx11plus_reg + 'v3.0\Setup' + lcid, 'InstallSuccess', regVersion);
+			NetFx35:
+				RegQueryDWordValue(HKLM, netfx11plus_reg + 'v3.5' + lcid, 'Install', regVersion);
+			NetFx40Client:
+				RegQueryDWordValue(HKLM, netfx11plus_reg + 'v4\Client' + lcid, 'Install', regVersion);
+			NetFx40Full:
+				RegQueryDWordValue(HKLM, netfx11plus_reg + 'v4\Full' + lcid, 'Install', regVersion);
+			NetFx4x:
+			begin
+				RegQueryDWordValue(HKLM, netfx11plus_reg + 'v4\Full' + lcid, 'Release', regVersion);
+				Result := (regVersion >= 378389); // 4.5.0+
+				Exit;
+			end;
+		end;
+		Result := (regVersion <> 0);
+	end;
+end;
+
+function netfxspversion(version: NetFXType; lcid: string): integer;
+var
+	regVersion: cardinal;
+begin
+	if (lcid <> '') then
+		lcid := '\' + lcid;
+
+	case version of
+		NetFx10:
+			//not supported
+			regVersion := -1;
+		NetFx11:
+			if (not RegQueryDWordValue(HKLM, netfx11plus_reg + 'v1.1.4322' + lcid, 'SP', regVersion)) then
+				regVersion := -1;
+		NetFx20:
+			if (not RegQueryDWordValue(HKLM, netfx11plus_reg + 'v2.0.50727' + lcid, 'SP', regVersion)) then
+				regVersion := -1;
+		NetFx30:
+			if (not RegQueryDWordValue(HKLM, netfx11plus_reg + 'v3.0' + lcid, 'SP', regVersion)) then
+				regVersion := -1;
+		NetFx35:
+			if (not RegQueryDWordValue(HKLM, netfx11plus_reg + 'v3.5' + lcid, 'SP', regVersion)) then
+				regVersion := -1;
+		NetFx40Client:
+			if (not RegQueryDWordValue(HKLM, netfx11plus_reg + 'v4\Client' + lcid, 'Servicing', regVersion)) then
+				regVersion := -1;
+		NetFx40Full:
+			if (not RegQueryDWordValue(HKLM, netfx11plus_reg + 'v4\Full' + lcid, 'Servicing', regVersion)) then
+				regVersion := -1;
+		NetFx4x:
+			if (RegQueryDWordValue(HKLM, netfx11plus_reg + 'v4\Full' + lcid, 'Release', regVersion)) then begin
+				if (regVersion >= 394747) then
+					regVersion := 62 // 4.6.2+
+				else if (regVersion >= 394254) then
+					regVersion := 61 // 4.6.1+
+				else if (regVersion >= 393295) then
+					regVersion := 60 // 4.6+
+				else if (regVersion >= 379893) then
+					regVersion := 52 // 4.5.2+
+				else if (regVersion >= 378675) then
+					regVersion := 51 // 4.5.1+
+				else if (regVersion >= 378389) then
+					regVersion := 50 // 4.5.0+
+				else
+					regVersion := -1;
+			end;
+	end;
+	Result := regVersion;
+end;
+
+[Setup]

Installer/scripts/products/fileversion.iss

@@ -0,0 +1,25 @@
+[Code]
+function GetFullVersion(VersionMS, VersionLS: cardinal): string;
+var
+	version: string;
+begin
+	version := IntToStr(word(VersionMS shr 16));
+	version := version + '.' + IntToStr(word(VersionMS and not $ffff0000));
+
+	version := version + '.' + IntToStr(word(VersionLS shr 16));
+	version := version + '.' + IntToStr(word(VersionLS and not $ffff0000));
+
+	Result := version;
+end;
+
+function fileversion(file: string): string;
+var
+	versionMS, versionLS: cardinal;
+begin
+	if GetVersionNumbers(file, versionMS, versionLS) then
+		Result := GetFullVersion(versionMS, versionLS)
+	else
+		Result := '0';
+end;
+
+[Setup]

Installer/scripts/products/stringversion.iss

@@ -0,0 +1,62 @@
+[Code]
+function stringtoversion(var temp: String): Integer;
+var
+	part: String;
+	pos1: Integer;
+
+begin
+	if (Length(temp) = 0) then begin
+		Result := -1;
+		Exit;
+	end;
+
+	pos1 := Pos('.', temp);
+	if (pos1 = 0) then begin
+		Result := StrToInt(temp);
+		temp := '';
+	end else begin
+		part := Copy(temp, 1, pos1 - 1);
+		temp := Copy(temp, pos1 + 1, Length(temp));
+		Result := StrToInt(part);
+	end;
+end;
+
+function compareinnerversion(var x, y: String): Integer;
+var
+	num1, num2: Integer;
+
+begin
+	num1 := stringtoversion(x);
+	num2 := stringtoversion(y);
+	if (num1 = -1) and (num2 = -1) then begin
+		Result := 0;
+		Exit;
+	end;
+
+	if (num1 < 0) then begin
+		num1 := 0;
+	end;
+	if (num2 < 0) then begin
+		num2 := 0;
+	end;
+
+	if (num1 < num2) then begin
+		Result := -1;
+	end else if (num1 > num2) then begin
+		Result := 1;
+	end else begin
+		Result := compareinnerversion(x, y);
+	end;
+end;
+
+function compareversion(versionA, versionB: String): Integer;
+var
+  temp1, temp2: String;
+
+begin
+    temp1 := versionA;
+    temp2 := versionB;
+    Result := compareinnerversion(temp1, temp2);
+end;
+
+[Setup]

Installer/scripts/products/winversion.iss

@@ -0,0 +1,49 @@
+[Code]
+var
+	WindowsVersion: TWindowsVersion;
+
+procedure initwinversion();
+begin
+	GetWindowsVersionEx(WindowsVersion);
+end;
+
+function exactwinversion(MajorVersion, MinorVersion: integer): boolean;
+begin
+	Result := (WindowsVersion.Major = MajorVersion) and (WindowsVersion.Minor = MinorVersion);
+end;
+
+function minwinversion(MajorVersion, MinorVersion: integer): boolean;
+begin
+	Result := (WindowsVersion.Major > MajorVersion) or ((WindowsVersion.Major = MajorVersion) and (WindowsVersion.Minor >= MinorVersion));
+end;
+
+function maxwinversion(MajorVersion, MinorVersion: integer): boolean;
+begin
+	Result := (WindowsVersion.Major < MajorVersion) or ((WindowsVersion.Major = MajorVersion) and (WindowsVersion.Minor <= MinorVersion));
+end;
+
+function exactwinspversion(MajorVersion, MinorVersion, SpVersion: integer): boolean;
+begin
+	if exactwinversion(MajorVersion, MinorVersion) then
+		Result := WindowsVersion.ServicePackMajor = SpVersion
+	else
+		Result := true;
+end;
+
+function minwinspversion(MajorVersion, MinorVersion, SpVersion: integer): boolean;
+begin
+	if exactwinversion(MajorVersion, MinorVersion) then
+		Result := WindowsVersion.ServicePackMajor >= SpVersion
+	else
+		Result := true;
+end;
+
+function maxwinspversion(MajorVersion, MinorVersion, SpVersion: integer): boolean;
+begin
+	if exactwinversion(MajorVersion, MinorVersion) then
+		Result := WindowsVersion.ServicePackMajor <= SpVersion
+	else
+		Result := true;
+end;
+
+[Setup]