mirror of
https://github.com/ckaczor/azuredatastudio.git
synced 2026-01-14 09:59:47 -05:00
5c63f7bdb5
This adds SQL Server Notebook as a built-in extension by pulling it from blob storage. It also adds support in mssql extension for reading the contribution points from other extensions. This will contribute troubleshooting and other books as widgets. In this commit: - Bundle the extension in the build - Bundle in sql.sh / sql.bat so it appears in local testing - Avoid installing in Stable. Should only appear in Dev/Insiders builds - Extensions with `notebook.books` contribution point will be discovered & their books available in MSSQL Coming later: - Integrate this with Maddy's work to show a Notebooks widget in the SQL Server big data cluster UI - When clause isn't supported yet for filtering. Will be done as we refactor towards more books for different server types
44 lines
984 B
Batchfile
44 lines
984 B
Batchfile
@echo off
|
|
setlocal
|
|
|
|
title VSCode Dev
|
|
|
|
pushd %~dp0\..
|
|
|
|
:: Node modules
|
|
if not exist node_modules call yarn
|
|
|
|
for /f "tokens=2 delims=:," %%a in ('findstr /R /C:"\"nameShort\":.*" product.json') do set NAMESHORT=%%~a
|
|
set NAMESHORT=%NAMESHORT: "=%
|
|
set NAMESHORT=%NAMESHORT:"=%.exe
|
|
set CODE=".build\electron\%NAMESHORT%"
|
|
|
|
:: Download Electron if needed
|
|
node build\lib\electron.js
|
|
if %errorlevel% neq 0 node .\node_modules\gulp\bin\gulp.js electron
|
|
|
|
:: Sync built-in extensions
|
|
node build\lib\builtInExtensions.js
|
|
|
|
:: Build
|
|
if not exist out node .\node_modules\gulp\bin\gulp.js compile
|
|
|
|
:: Configuration
|
|
set NODE_ENV=development
|
|
set VSCODE_DEV=1
|
|
set VSCODE_CLI=1
|
|
set ELECTRON_DEFAULT_ERROR_MODE=1
|
|
set ELECTRON_ENABLE_LOGGING=1
|
|
set ELECTRON_ENABLE_STACK_DUMPING=1
|
|
|
|
:: Launch Code
|
|
|
|
:: Use the following to get v8 tracing:
|
|
:: %CODE% --js-flags="--trace-hydrogen --trace-phase=Z --trace-deopt --code-comments --hydrogen-track-positions --redirect-code-traces" . %*
|
|
|
|
%CODE% . %*
|
|
|
|
popd
|
|
|
|
endlocal
|